**COMO CREAR UN PROGRAMA ILE**

IBM siempre ha tratado de mejorar la forma de programar en el iSeries.  
Basados en ultimas reuniones con IBM, este es el mejor proceso para crear un programa ILE.

1. Se crea un copybook terminado en \_H el cual contendrá todos los prototipos, (Nota: Este miembro no se compila):

**INGRMAT\_H.RPGLE**

\*\*Free

//\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

// Prototipos para el systema de calulos

//\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

//\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

// PROTOTIPOS

//\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

//\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

// Prototipo PrAddInts

// recibe dos parametros tipo packed

// devuelve un valor tipo packed

//\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dcl-PR PrAddInts Packed(15:0) extproc('PrAddInts');

\*N Packed(15:0) CONST;

\*N Packed(15:0) CONST;

End-PR;

//\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

// Prototipo PrSubInts

// recibe dos parametros tipo packed

// devuelve un valor tipo packed

//\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dcl-PR PrSubInts Packed(15:0) extproc('PrSubInts');

\*N Packed(15:0) CONST;

\*N Packed(15:0) CONST;

End-PR;

1. Se crea el miembro **NO MAIN**, se adiciona el copybook /COPY del paso 1 y se crea el modulo con el mandato **CRTPGMMOD** asi:

**INGRCALCUL.RPGLE**

\*\*Free

Ctl-Opt nomain;

Ctl-Opt option(\*srcstmt:\*nodebugio);

Ctl-Opt datfmt(\*ISO);

/COPY INGDOJO/QRPGLESRC,INGRMAT\_H

//\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

// Proceso PrAddInts

// recibe dos parametros tipo packed (P1 y P2)

// devuelve un valor tipo packed (p1 + p2)

//\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dcl-Proc PrAddInts EXPORT;

Dcl-PI \*N packed(15:0);

inP1 Packed(15:0) CONST;

inP2 Packed(15:0) CONST;

End-PI;

RETURN inP1 + inP2;

End-Proc;

//\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

// Proceso PrSubInts

// recibe dos parametros tipo packed (P1 y P2)

// devuelve un valor tipo packed (p1 - p2)

//\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dcl-Proc PrSubInts EXPORT;

Dcl-PI \*N Packed(15:0);

inP1 Packed(15:0) CONST;

inP2 Packed(15:0) CONST;

End-PI;

RETURN inP1 - inP2;

End-Proc;

CRTRPGMOD MODULE(INGDOJO/INGRCALCUL)

SRCFILE(INGDOJO/QRPGLESRC)

SRCMBR(INGRCALCUL)

1. Se crea el Binding **BND** donde se cualifican los procedimientos contenidos en el módulo, (Nota: este miembro no se compila).

**INGBNDMATH.BND**

STRPGMEXP PGMLVL(\*CURRENT) LVLCHK(\*YES) SIGNATURE(\*GEN)

EXPORT SYMBOL('PrAddInts')

EXPORT SYMBOL('PrSubInts')

ENDPGMEXP

1. Creamos el Service Program, enlazando el **MODULO** y el **BND**, ASI:

CRTSRVPGM SRVPGM(INGDOJO/CTRSRVMATH)

MODULE(INGDOJO/INGRCALCUL)

SRCFILE(INGDOJO/QRPGLESRC)

SRCMBR(INGBNDMATH)

USRPRF(\*OWNER)

AUT(\*ALL)

y un mensaje asi debe de aparecer

Programa de servicio CTRSRVMATH creado en biblioteca INGDOJO.

1. Creamos el programa principal y enlazamos el Service program y el Binding asi:

**INGRPROMAT.RPGLE**

\*\*Free

//------------------------------------------------------------------------\*

//Programa : INGRPROMAT

//Tarea : PMO12345

//Objetivo : Programa de Procesos Matematicos

//

//Fecha : 23 Febrero 2021

//Autor : NINGSW

//------------------------------------------------------------------------\*

//------------------------------------------------------------------------\*

// Declaración de Control

//------------------------------------------------------------------------\*

Ctl-Opt option(\*srcstmt:\*nodebugio);

Ctl-Opt datfmt(\*ISO);

//------------------------------------------------------------------------\*

// Declaración de los /COPY o /INCLUDE

//------------------------------------------------------------------------\*

/COPY INGDOJO/QRPGLESRC,INGRMAT\_H

//------------------------------------------------------------------------\*

// Declaración de Archivos DDS

//------------------------------------------------------------------------\*

//------------------------------------------------------------------------\*

// Declaración de los Prototipos

//------------------------------------------------------------------------\*

//------------------------------------------------------------------------\*

// Declaración de las Structuras de Datos

//------------------------------------------------------------------------\*

//------------------------------------------------------------------------\*

// Declaración de las variables

//------------------------------------------------------------------------\*

Dcl-S wValorInicial Packed(15:0) Inz(1);

Dcl-S wValorFinal Packed(15:0) Inz(1);

Dcl-S wValorTotal Packed(15:0) inz(0);

//------------------------------------------------------------------------\*

// Declaración de las constantes

//------------------------------------------------------------------------\*

//------------------------------------------------------------------------\*

// Proceso Main

//------------------------------------------------------------------------\*

// Calculation specifications

wValorTotal = PrAddInts(wValorInicial:wValorFinal);

dsply wValorTotal;

\*inlr = \*off;

Return;

//------------------------------------------------------------------------\*

// Declaración de los Procedures

//------------------------------------------------------------------------\*

Compilamos con 15 para crear el modulo y despues creamos el programa:

CRTPGM PGM(INGDOJO/INGRPROMAT)

MODULE(INGDOJO/INGRPROMAT)

BNDSRVPGM((INGDOJO/CTRSRVMATH))

ACTGRP(\*CALLER)

USRPRF(\*OWNER)

AUT(\*ALL)

Cuando ejecutamos nuestro programa este será el resultado:

Visualizar Mensajes de Programa

Se utiliza clase de reserva para trabajo.

Trabajo 400177/DDSSTIASB/QPADEV008P arrancado el 02/23/21 a las 10:58:48 en

DSPLY 2

Pulse Intro para continuar.

F3=Salir F12=Cancelar